?login_element?

Subversion Repositories NedoOS

Rev

Rev 1918 | Rev 1962 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.        IF corr_coord
  2. CORR_COORD
  3.        LD A,L
  4.        OR A
  5.        jr NZ,$+3
  6.        INC L
  7.        INC A
  8.        jr NZ,$+3
  9.        DEC L
  10.        LD A,H
  11.        OR A
  12.        jr NZ,$+3
  13.        INC H
  14.        INC A
  15.        RET NZ
  16.        DEC H
  17.         RET
  18.        ENDIF
  19.  
  20. RAYPREPXY
  21. ;TODO брать координаты не из прерывания!!!
  22.        IF optfast
  23.         LD HL,(IMcurDX)
  24.         LD A,H
  25.         OR L
  26.         LD HL,(IMcurDY)
  27.         OR H
  28.         OR L
  29.         LD A,lowmaxscale
  30.         jr Z,$+4
  31.         LD A,0;-1
  32.         LD (foptfast),A
  33.        ENDIF
  34. IMcurXx=$+1
  35.         LD HL,#0F80 ;#0580
  36.        IF corr_coord
  37.         CALL CORR_COORD
  38.        ENDIF
  39.         LD (curXx),HL
  40. IMcurYy=$+1
  41.         LD HL,#0180+(map&#FF00) ;#A580
  42.        IF corr_coord
  43.         CALL CORR_COORD
  44.        ENDIF
  45.         LD (curYy),HL
  46.         LD A,(IMavision+1)
  47.        LD (curangle),A
  48.         SUB 32
  49.         LD L,A
  50.         LD H,0
  51.         ADD HL,HL
  52.         ADD HL,HL
  53.         LD A,L
  54.         LD (avision4L),A
  55.         LD A,H
  56.         LD (avision4H),A
  57.         LD HL,(cury-1)
  58.         LD A,(curx)
  59.         LD L,A
  60.         LD (cur00yx),HL
  61.         LD (cur01yx),HL
  62.       ;LD A,L ;основное направление
  63.        CPL ;1-основное направление
  64.        LD L,A
  65.         LD (cur10yx),HL
  66.         LD (cur11yx),HL
  67.        CPL ;основное направление
  68.         LD L,H,H,A
  69.         LD (cur00xy),HL
  70.         LD (cur01xy),HL
  71.        LD A,L ;1-основное направление
  72.        CPL ;основное направление
  73.        LD L,A
  74.         LD (cur10xy),HL
  75.         LD (cur11xy),HL
  76.         LD HL,(curX)
  77.         LD A,(curY)
  78.         LD H,A
  79.        ;LD (curYX),HL
  80.         LD (ray00yx_YX),HL
  81.         LD (ray01yx_YX),HL
  82.         LD (ray10yx_YX),HL
  83.         LD (ray11yx_YX),HL
  84.         LD (ray00xy_YX),HL
  85.         LD (ray01xy_YX),HL
  86.         LD (ray10xy_YX),HL
  87.         LD (ray11xy_YX),HL
  88.         SET mapdifbit,L
  89.         LD (ray00xy_YX2),HL
  90.         LD (ray01xy_YX2),HL
  91.         LD (ray10xy_YX2),HL
  92.         LD (ray11xy_YX2),HL
  93.         ret
  94. SCAN
  95.         call RAYPREPXY
  96.  
  97.         ;TODO чтобы узнать, какая дверь открывается, надо её отметить на самой карте (с обеих сторон)
  98.  
  99.       IF interpolate == 0
  100.  
  101.        IF lores
  102.         LD L,0;2*(32-scrwid)
  103.         LD HY,SCRWIDPIX;scrwid*4
  104.        ELSE
  105.         LD L,0;4*(32-scrwid)
  106.         LD HY,SCRWIDPIX;scrwid*8
  107.        ENDIF
  108. RAY0
  109.         LD A,L
  110.         LD (cura),A
  111.         CALL RAYCAST
  112.        LD HL,(cura)
  113.         LD H,distbuf/256+2
  114.         LD (HL),C ;dist (scale#)
  115.         DEC H
  116.         LD (HL),B ;texx
  117.         DEC H
  118.         RRCA ;CY=0
  119.         LD A,(DE) ;ID(YX)
  120.          ;ld a,0xc0
  121.         LD (HL),A ;ID
  122.         INC L
  123.         DEC HY
  124.         JP NZ,RAY0
  125.  
  126.       ELSE ;interpolate
  127. main_step=interpolate;16
  128.          ;oldscan=RAYCAST(0)
  129.         XOR A
  130.         LD L,A
  131.         LD (cura),A
  132.         CALL RAYCAST
  133.         EXX
  134.          ;main_a=main_step-1
  135.         LD L,main_step-1
  136.        ;IF lores
  137.        ; LD HY,scrwid*4/main_step
  138.        ;ELSE
  139.        ; LD HY,scrwid*8/main_step
  140.        ;ENDIF
  141.        ld hy,SCRWIDPIX/main_step
  142.          ;repeat {
  143. ;L=main_a
  144. ;BCDE'=oldscan
  145. ;BCDE=newscan
  146. RAY0
  147.          ;newscan=RAYCAST(main_a)
  148.         LD A,L
  149.         LD (cura),A
  150.         CALL RAYCAST
  151.        LD HL,(cura)
  152.          ;INTERPOLATE_SUB(main_a, main_step, oldscan, newscan)
  153.         LD A,main_step
  154.         LD H,distbuf/256+2
  155.         LD (HL),C ;dist (scale#)
  156.         DEC H
  157.         LD (HL),B ;texx
  158.         DEC H
  159.         RRCA ;CY=0
  160.         CALL INTERPOLATE_SUB
  161.         LD A,(DE) ;ID(YX)
  162.          ;ld a,0xc0
  163.         LD (HL),A ;ID
  164.          ;oldscan=newscan
  165.         LD A,L
  166.         EXX
  167.          ;main_a+=main_step
  168.         ADD A,main_step
  169.         LD L,A
  170.          ;} until(main_a>255)
  171.         DEC HY
  172.         JP NZ,RAY0
  173.       ENDIF ;interpolate
  174.         RET
  175.  
  176. ;((b+f)/2)^2-b^2/4-f^2/4
  177. ;a=e
  178.        MACRO MULPOS
  179.         LD H,tsqr2/256
  180.         ADD A,C
  181.         RRA
  182.         LD L,A
  183.         LD A,(HL)
  184.         INC H
  185.         LD L,C
  186.         SUB (HL)
  187.         LD L,E
  188.         SUB (HL)
  189.        ENDM
  190.  
  191.        MACRO DIVPOS
  192.         SRL C
  193.        DUP 7
  194.         ADD A,C
  195.         jr NC,$+3
  196.         SUB C
  197.         RL B
  198.         ADD A,A
  199.        EDUP
  200.         ADD A,C
  201.         LD A,B
  202.         RLA
  203.        ENDM
  204.  
  205.        MACRO DIVNEG
  206.         SRL C
  207.        DUP 7
  208.         SUB C
  209.         jr NC,$+3
  210.         ADD A,C
  211.         RL B
  212.         ADD A,A
  213.        EDUP
  214.         SUB C
  215.         LD A,B
  216.         RLA
  217.        ENDM
  218.  
  219.  
  220. ;Y растёт вверх
  221. RAYCAST
  222. ;L=(cura)=угол на экране
  223. ;портит ABCDEHLIX
  224.         ld a,(doortimer)
  225.         ld ly,a
  226.         LD H,tda/256
  227.         LD A,(HL)
  228. avision4L=$+1
  229.         ADD A,0
  230.         LD (rayrealangle),A
  231.         LD L,A
  232. avision4H=$+1
  233.         ADC A,0
  234.         SUB L ;a1..0 = 0..3 ~ sector 1..4
  235.        ;LD H,tctg/256 ;-pi/4..+pi/4
  236.        INC H
  237.         LD C,(HL) ;ystep or xstep
  238.         LD HX,-1 ;IX=dist*cos
  239.         RRA
  240.         jr NC,ray13
  241.         RRA
  242.         JP NC,ray2
  243.         JP ray4
  244. ray13   RRA
  245.         JP NC,ray1
  246.         JP ray3
  247.  
  248.         macro INCR num ;0..5 = bcdehl
  249.         db 0x04+(8*(num))
  250.         endm
  251.  
  252.         macro DECR num ;0..5 = bcdehl
  253.         db 0x05+(8*(num))
  254.         endm
  255.  
  256. ;RAY 1,1,H,D,y,x
  257.        MACRO RAY mainplus,secplus,maindirhlreg,maindirdereg,maindir,secdir
  258. ;mainplus=\0 ;основное направление положительно
  259. ;secplus=\1 ;побочное направление положительно
  260. ;\2=основное направление для hl (YX)
  261. ;\4=основное направление для de (yx)
  262. ;\6=основное направление (0=x, 1=y)
  263. ;\7=побочное направление (0=x, 1=y)
  264. ;c=побочный шаг
  265.         LD A,E ;основное направление
  266.         LD LX,A ;IX=dist*cos
  267.         MULPOS ;a = a*c
  268.       IF secplus ;побочное направление положительно
  269.         ADD A,D ;побочное направление
  270.         LD B,A ;texx
  271. ray0176_YX=$+1
  272.         LD HL,0 ;hl = основная стенка
  273.        IF maindir != 0 ;"\6\6"-"xx"
  274. ray0176_YX2=$+1
  275.         LD DE,0 ;set mapdifbit ;осн.напр. y, побочное x
  276.        ELSE
  277.         LD D,H ;осн.напр. x, побочное y
  278.         ld E,L
  279.        ENDIF ;de = побочная стенка
  280.         jr NC,2f;raynshort\0\1\7\6 ;точно не пересечение по побоч.напр.
  281.         INCR maindirdereg^1 ;secdirdereg;INC \5 ;e/d
  282.         LD A,(DE)
  283.          add a,a
  284.          cp ID_DOOR*2;128+(22*2)
  285.          jr z,9f
  286.          ld a,(de)
  287.         RLA
  288.         jp C,1f;raysec\0\1\7\6 ;выход по побочной стене
  289. 9
  290.         INCR maindirhlreg^1 ;secdirhlreg;INC \3 ;l/h
  291. 2;raynshort\0\1\7\6
  292.        IF maindir != 1 ;"\6\6"-"yy"
  293.         SET mapdifbit,L
  294.        ENDIF
  295.       ELSE ;побочное направление отрицательно
  296.         LD L,A
  297.         LD A,D ;побочное направление
  298.         SUB L
  299.         LD B,A ;texx
  300. ray0176_YX=$+1
  301.         LD HL,0 ;hl = основная стенка
  302.        IF maindir != 0 ;"\6\6"-"xx"
  303. ray0176_YX2=$+1
  304.         LD DE,0 ;set mapdifbit ;осн.напр. y, побочное x
  305.        ELSE
  306.         LD D,H ;осн.напр. x, побочное y
  307.         ld E,L
  308.        ENDIF ;de = побочная стенка
  309.         jr NC,2f;raynshort\0\1\7\6 ;точно не пересечение по побоч.напр.
  310.         LD A,(DE)
  311.          add a,a
  312.          cp ID_DOOR*2;128+(22*2)
  313.          jr z,9f
  314.          ld a,(de)
  315.         RLA
  316.         jp C,1f;raysec\0\1\7\6 ;выход по побочной стене
  317. 9
  318. ;продолжение по основному направлению
  319.         DECR maindirhlreg^1 ;secdirhlreg
  320.         DECR maindirdereg^1 ;secdirdereg
  321. 2;raynshort\0\1\7\6
  322.        IF maindir != 1 ;"\6\6"-"yy"
  323.         SET mapdifbit,L
  324.        ENDIF
  325.       ENDIF
  326. ;первый (короткий) шаг закончен, теперь идём полными шагами в цикле
  327. 3;raynsec=$;\0\1\7\6
  328.         INC HX
  329.        IF mainplus ;основное направление положительно
  330.         INCR maindirhlreg;INC \2 ;h/l
  331.        ENDIF
  332.         LD A,(HL)
  333.          add a,a
  334.          cp ID_DOOR*2;128+(22*2)
  335.          jp z,4f;doorhlq ;куб двери
  336.          ld a,(hl)
  337.         RLA
  338.         JP C,rayhlq ;b=texx ;выход по основной стене
  339. 13
  340.        IF mainplus ;основное направление положительно
  341.         INCR maindirdereg;INC \4 ;d/e
  342.        ELSE
  343.         DECR maindirhlreg
  344.         DECR maindirdereg
  345.        ENDIF
  346.         LD A,B ;texx
  347.        IF secplus ;побочное направление положительно
  348.         ADD A,C ;побочный шаг
  349.        ELSE
  350.         SUB C ;побочный шаг
  351.        ENDIF
  352.         LD B,A ;texx
  353.         jr NC,3b;raynsec;\0\1\7\6 ;точно не пересечение по побоч.напр.
  354. 12
  355.        IF secplus ;побочное направление положительно
  356.         INCR maindirdereg^1 ;secdirdereg;INC \5 ;e/d
  357.        ENDIF
  358.         LD A,(DE)
  359.          add a,a
  360.          cp ID_DOOR*2;128+(22*2)
  361.          jr z,5f
  362.          ld a,(de)
  363.         RLA
  364.         jp C,1f;raysec\0\1\7\6 ;выход по побочной стене
  365. 9
  366.        IF secplus ;побочное направление положительно
  367.         INCR maindirhlreg^1 ;secdirhlreg;INC \3 ;l/h
  368.        ELSE        ;побочное направление отрицательно
  369.         DECR maindirhlreg^1 ;secdirhlreg
  370.         DECR maindirdereg^1 ;secdirdereg
  371.        ENDIF
  372.         JP 3b;raynsec;\0\1\7\6
  373.  
  374. 7 ;возврат из куба двери, если дверь открыта (в следующей стене игнорить дверь!!!)
  375.         LD A,B ;texx
  376.        IF secplus ;побочное направление положительно
  377.         ADD A,C ;побочный шаг
  378.        ELSE
  379.         SUB C ;побочный шаг
  380.        ENDIF
  381.         LD B,A ;texx
  382.         jr C,12b;raynsec;\0\1\7\6 ;точно не пересечение по побоч.напр.
  383. ;3;raynsec=$;\0\1\7\6
  384.         INC HX
  385.        IF mainplus ;основное направление положительно
  386.         INCR maindirhlreg;INC \2 ;h/l
  387.        ENDIF
  388.         jr 13b ;считаем, что стены впереди нет, продолжаем как обычно
  389.  
  390. ;куб двери по побочному шагу
  391. 5
  392.         ld a,(de)
  393.         rla
  394.         jr nc,$+5 ;закрытая дверь
  395.         ld ly,0
  396.        IF secplus ;побочное направление положительно
  397.         INCR maindirhlreg^1 ;secdirhlreg;INC \3 ;l/h
  398.        ELSE        ;побочное направление отрицательно
  399.         DECR maindirhlreg^1 ;secdirhlreg
  400.         DECR maindirdereg^1 ;secdirdereg
  401.        ENDIF
  402.         INC HX
  403.         bit 7,B ;texx
  404.        IF secplus ;побочное направление положительно
  405.         jp z,rayhlq ;видим основную стену до двери
  406.        ELSE
  407.         jp nz,rayhlq ;видим основную стену до двери
  408.        ENDIF
  409.         ;ld b,10 ;сплошной голубой (0=сплошной серый)
  410.         ;jp z,rayhlq
  411.  
  412.        IF secplus ;побочное направление положительно
  413.         INCR maindirdereg^1 ;secdirdereg;INC \5 ;e/d
  414.        ENDIF
  415.         ;jp rayhlq ;дверь открыта, выход по основной стене
  416.          ;dec hx
  417.          ld a,b ;texx
  418.          add a,128
  419.          ;ld b,a
  420.         ;jr 1f ;jr C,8f;raysec\0\1\7\6 ;выход по побочной стене
  421.         ;LD A,B
  422.        IF secplus ;побочное направление положительно
  423.         SUB C
  424.        else
  425.         ADD A,C
  426.        endif
  427. ;a=texx как был
  428.         EXD
  429.         ;ex de,hl
  430.         ;jp rayhlq ;дверь открыта, выход по основной стене
  431.         push bc
  432.        IF secplus ;побочное направление положительно
  433.         DIVPOS ;texx(a)/step(c), портит b,c
  434.        ELSE
  435.         DIVNEG ;texx(a)/step(c), портит b,c
  436.        ENDIF
  437.         pop bc
  438.        IF mainplus ;основное направление положительно
  439.         CPL
  440.          ;push hl
  441.          ;ld hl,timer
  442.          add a,ly;(hl)
  443.          jr c,6f ;b=texx, выход по осн. стене (полуоткрытая дверь)
  444.         LD B,A ;b=texx
  445.         sub ly;(hl)
  446.          ;pop hl
  447.        ELSE
  448.          ;push hl
  449.          ;ld hl,timer
  450.          add a,ly;(hl)
  451.          jr c,6f ;выход по осн. стене (полуоткрытая дверь)
  452.         LD B,A ;b=texx
  453.         sub ly;(hl)
  454.         CPL
  455.          ;pop hl
  456.        ENDIF
  457.          dec hx
  458.         JP raydeq ;c,de не важны
  459. 6 ;выход по осн. стене (полуоткрытая дверь)
  460.         ;pop hl
  461.         ex de,hl
  462.         jp rayhlq ;b=texx
  463.  
  464. ;куб двери по основному шагу
  465. 4
  466.         bit 7,(HL)
  467.         jr z,$+5 ;закрытая дверь
  468.         ld ly,0
  469. ;проверить, что позади дверь, тогда выход в 13b (т.е. впереди пусто)
  470.        IF mainplus ;основное направление положительно
  471.         DECR maindirhlreg;INC \4 ;d/e
  472.        ELSE
  473.         INCR maindirhlreg
  474.        ENDIF
  475.         ld a,(hl)
  476.        IF mainplus ;основное направление положительно
  477.         INCR maindirhlreg;INC \4 ;d/e
  478.        ELSE
  479.         DECR maindirhlreg
  480.        ENDIF
  481.          add a,a
  482.          cp ID_DOOR*2;128+(22*2)
  483.         jp z,13b ;позади дверь, значит, впереди пусто
  484. ;
  485.         srl c ;побочный шаг
  486.        IF mainplus ;основное направление положительно
  487.         INCR maindirdereg;INC \4 ;d/e
  488.        ELSE
  489.         DECR maindirhlreg
  490.         DECR maindirdereg
  491.        ENDIF
  492.         LD A,B ;texx
  493.        IF secplus ;побочное направление положительно
  494.         ADD A,C ;побочный шаг
  495.         LD B,A ;texx
  496.         SUB C ;побочный шаг
  497.        ELSE
  498.         SUB C ;побочный шаг
  499.         LD B,A ;texx
  500.         ADD A,C ;побочный шаг
  501.        ENDIF
  502.         jr c,2f
  503.         ex af,af' ;'
  504.         ld a,ly;(timer)
  505.         add a,b
  506.         ld b,a
  507.         jr nc,11f ;дверь по основному направлению
  508.         ex af,af' ;'
  509.         ld b,a ;texx как был
  510.         sla c ;побочный шаг как был
  511.         jp 7b ;нет двери
  512. 11      
  513.         jp doorhlq;3b;raynsec;\0\1\7\6 ;точно не пересечение по побоч.напр.
  514. 2;куб двери по основному шагу - выход по побочной стене
  515.        IF secplus ;побочное направление положительно
  516.         INCR maindirdereg^1 ;secdirdereg;INC \5 ;e/d
  517.        ENDIF
  518.  
  519. ;побочная стена при шаге половинками
  520.         sla c ;побочный шаг как был
  521.         jr 8f
  522.        
  523. ;побочная стена
  524. 1;raysec\0\1\7\6
  525.         LD A,B
  526.        IF secplus ;побочное направление положительно
  527.         SUB C
  528.        else
  529.         ADD A,C
  530.        endif
  531. 8
  532. ;a=texx как был
  533.         EXD
  534.        IF secplus ;побочное направление положительно
  535.         DIVPOS ;texx(a)/step(c)
  536.        ELSE
  537.         DIVNEG ;texx(a)/step(c)
  538.        ENDIF
  539.        IF mainplus ;основное направление положительно
  540.         CPL
  541.         LD B,A ;b=texx
  542.        ELSE
  543.         LD B,A ;b=texx
  544.         CPL
  545.        ENDIF
  546.         JP raydeq
  547.        ENDM
  548.  
  549. ;mainplus=\0 ;основное направление положительно
  550. ;secplus=\1 ;побочное направление положительно
  551. ;\2=основное направление для hl = 4..5
  552. ;\4=основное направление для de = 2..3
  553. ;\6=основное направление
  554. ;\7=побочное направление
  555. ;c = ystep or xstep (шаг по побочному направлению) всегда положительный
  556. ;HX=-1 ;IX=dist*cos
  557. ;сейчас l=angle
  558. ray1
  559.         BIT 7,L
  560.         JP NZ,ray1b
  561.         ;RAY 1,1,L,E,x,y ;1a
  562. cur11yx=$+1
  563.         LD DE,0
  564.         RAY 1,1,5,3,0,1;x,y ;1a
  565. ;cur11yx=cur0176
  566. ray11yx_YX=ray0176_YX
  567. ;ray11yx_YX2=ray0176_YX2
  568. ray1b
  569.         ;RAY 1,1,H,D,y,x ;1b
  570. cur11xy=$+1
  571.         LD DE,0
  572.         RAY 1,1,4,2,1,0;y,x ;1b
  573. ;cur11xy=cur0176
  574. ray11xy_YX=ray0176_YX
  575. ray11xy_YX2=ray0176_YX2
  576. ray2
  577.         BIT 7,L
  578.         JP NZ,ray2b
  579.         ;RAY 1,0,H,D,y,x ;2a
  580. cur10xy=$+1
  581.         LD DE,0
  582.         RAY 1,0,4,2,1,0;y,x ;2a
  583. ;cur10xy=cur0176
  584. ray10xy_YX=ray0176_YX
  585. ray10xy_YX2=ray0176_YX2
  586. ray2b
  587.         ;RAY 0,1,L,E,x,y ;2b
  588. cur01yx=$+1
  589.         LD DE,0
  590.         RAY 0,1,5,3,0,1;x,y ;2b
  591. ;cur01yx=cur0176
  592. ray01yx_YX=ray0176_YX
  593. ;ray01yx_YX2=ray0176_YX2
  594. ray3
  595.         BIT 7,L
  596.         JP NZ,ray3b
  597.         ;RAY 0,0,L,E,x,y ;3a
  598. cur00yx=$+1
  599.         LD DE,0
  600.         RAY 0,0,5,3,0,1;x,y ;3a
  601. ;cur00yx=cur0176
  602. ray00yx_YX=ray0176_YX
  603. ;ray00yx_YX2=ray0176_YX2
  604. ray3b
  605.         ;RAY 0,0,H,D,y,x ;3b
  606. cur00xy=$+1
  607.         LD DE,0
  608.         RAY 0,0,4,2,1,0;y,x ;3b
  609. ;cur00xy=cur0176
  610. ray00xy_YX=ray0176_YX
  611. ray00xy_YX2=ray0176_YX2
  612. ray4
  613.         BIT 7,L
  614.         JP NZ,ray4b
  615.         ;RAY 0,1,H,D,y,x ;4a
  616. cur01xy=$+1
  617.         LD DE,0
  618.         RAY 0,1,4,2,1,0;y,x ;4a
  619. ;cur01xy=cur0176
  620. ray01xy_YX=ray0176_YX
  621. ray01xy_YX2=ray0176_YX2
  622. ray4b
  623.         ;RAY 1,0,L,E,x,y ;4b
  624. cur10yx=$+1
  625.         LD DE,0
  626.         RAY 1,0,5,3,0,1;x,y ;4b
  627. ;cur10yx=cur0176
  628. ray10yx_YX=ray0176_YX
  629. ;ray10yx_YX2=ray0176_YX2
  630.  
  631. doorhlq
  632.         ld a,128
  633.         jr raydeq
  634. rayhlq_texxaxorb
  635.         xor b
  636.         ld b,a
  637. rayhlq
  638.         XOR A
  639. raydeq
  640. ;b=texx
  641. ;hl=YX
  642. ;dist*cos=ix+a
  643.  
  644.        PUSH HL
  645.         ADD A,LX
  646.         LD L,A
  647.         ADC A,HX
  648.         SUB L
  649.         LD H,A
  650. ;HL=dist*cos=128..#3fff
  651.  
  652. ;приводим к 128..255
  653.         LD DE,#000
  654.         LD A,L
  655.         jr Z,TOLOGRLQ
  656.        DUP 5;6
  657.         INC D
  658.         SRL H
  659.         RRA
  660.         jr Z,TOLOGRLE
  661.        EDUP
  662. TOLOGRLQ ;
  663.         OR A
  664.         JP M,$+5 ;>=128
  665.         LD A,128 ;<128
  666. TOLOGRLE ;
  667.         LD L,A ;128..255
  668.        ;D=0..5
  669.         LD H,tlogd/256
  670. ;2.делим на cos
  671. rayrealangle=$+1
  672.         LD A,(tlogcos) ;0..63
  673.         ADD A,(HL) ;log(dist/2^N) = 128..255 for arg>=128
  674.        IF debug
  675.        jr NC,$+3
  676.        INC D
  677.        ENDIF
  678.  
  679. ;3.умножение на corrdist(scrX) - получаем k/масштаб
  680. ;(сокращаем расстояние по краям в sqrt(2) раз)
  681. ;corrdist(scrX)=1/sqrt(1+scrX^2), где scrX=-1..+1
  682. ;из него номер таблицы масштабирования
  683. cura=$+1
  684.         LD HL,tcorrlogd ;L=scrX=0..255="-127.5..127.5"
  685.         SUB (HL) ;64..128
  686.        IF debug
  687.        jr NC,DEBBP
  688.        DEC D
  689.        JP P,DEBBP
  690.        INC D
  691.        XOR A
  692. DEBBP ;
  693.        ENDIF
  694.         LD L,A
  695.         LD H,tlogd2sca/256
  696.          SRA D
  697.          RR E ;DE=+0,+#80,..+#300
  698.         ADD HL,DE
  699.        IF debug
  700.         BIT 7,(HL)
  701.         jr NZ,$
  702.        ENDIF
  703.         LD C,(HL) ;dist(scale#)=63..1;127..1
  704.                   ;todo linear scale, recalc in DRAWWALLS
  705.          SCF
  706.          RR B ;texx=0x80..0xFF
  707.        IF scale64
  708.         SRL B ;texx=0x40..0x7F
  709.        ENDIF
  710.        POP DE
  711.         RET
  712.  
  713.        IF interpolate
  714.        IF 0
  715. I_SUB_INTERt ;
  716.         POP HL  ;
  717.         PUSH HL ;de
  718.         LD A,D
  719.         SUB H
  720.         jr NZ,holeny
  721.         LD A,E
  722.         SUB L
  723.         JP Z,I_SUB_INTER ;продолжение стены
  724.         DEC A
  725.         CP 3
  726.         jr C,nhole
  727.         JP isubneq
  728. holeny ;
  729.         DEC A
  730.         CP 3
  731.         jr NC,isubneq
  732.         LD A,E
  733.         CP L
  734.         jr NZ,isubneq
  735. nhole ;
  736.        ENDIF
  737. I_SUB_INTER
  738.          ; rightscan=Middlescan
  739.         LD A,C
  740.         EXX
  741.         ADD A,C
  742.         RRA
  743.         LD C,A ;dist
  744.         EXX
  745.         LD A,B
  746.         EXX
  747.         ADD A,B
  748.         RRA
  749.         LD B,A ;texx
  750. I_SUB_SCANQ ;
  751.          ;INTERPOLATE_SUB(a-step, step, leftscan, rightscan);r=M
  752.        PUSH HL ;step,a
  753.         LD A,L
  754.         SUB H
  755.         LD L,A ;a-step
  756.         LD A,H
  757.         LD H,distbuf/256+2
  758.         LD (HL),C ;dist
  759.         DEC H
  760.         LD (HL),B ;texx
  761.         DEC H
  762.         RRCA
  763.         CALL NC,INTERPOLATE_SUB
  764.         LD A,(DE) ;ID
  765.          ;ld a,0xc0
  766.         LD (HL),A ;ID
  767.          ;leftscan=rightscan ;=Middlescan
  768.         EXX
  769.        POP HL ;step,a
  770.          ;pop(rightscan)
  771.         POP DE
  772.         pop BC
  773.          ;INTERPOLATE_SUB(a, step, leftscan, rightscan) ;l=M,r=R
  774.          ;scan[a]=rightscan
  775.          ;if (step==1) exit
  776.         LD A,H
  777.         LD H,distbuf/256+2
  778.         LD (HL),C ;dist
  779.         DEC H
  780.         LD (HL),B ;texx
  781.         DEC H
  782.         RRCA
  783.         RET C
  784. INTERPOLATE_SUB
  785. ;L=a
  786. ;A=step/2                 ;not preserved
  787. ;BCDE'=leftscan ;(a-step) ;not preserved
  788. ;BCDE=rightscan ;(a)
  789. ;CY=0
  790.        EXA
  791.         LD A,(DE) ;ID
  792.         LD (HL),A ;ID ;texx,dist are written already
  793.        EXA
  794.          ;step=step/2
  795.         LD H,A
  796.          ;push(rightscan)
  797.         PUSH BC
  798.         push DE
  799.          ;if(rightscan.yx==leftscan.yx)
  800.      ;LD A,(DE)
  801.         EXX
  802.      ;EXD
  803.      ;XOR (HL)
  804.      ;EXD
  805.      ;JP Z,I_SUB_INTERt
  806.         POP HL  ;
  807.         PUSH HL ;de
  808.         ;OR A
  809.         SBC HL,DE ;CY=0
  810.         JP Z,I_SUB_INTER
  811. isubneq
  812.          ; rightscan=RAYCAST(a-step)
  813.         EXX
  814.         PUSH HL
  815.         LD A,L
  816.         SUB H
  817.         LD L,A ;a-step
  818.         LD (cura),A
  819.         CALL RAYCAST
  820.         POP HL
  821.         JP I_SUB_SCANQ
  822.          ;else - see above
  823.        ENDIF ;interpolate
  824.  
  825.  
  826. ;============================
  827.        IF sprites
  828. viewrange=6
  829.  
  830. DOSORTSPRITES=1
  831. ;CURSPRITES_RECSZ=5;4
  832.  
  833. SCANMONS
  834.         LD A,(curX)
  835.         SUB viewrange
  836.         LD (scmonX),A
  837.         LD A,(curY)
  838.         SUB viewrange
  839.         LD (scmonY),A
  840.        LD HL,cursprites
  841.       if DOSORTSPRITES
  842.        LD (HL),0 ;end of sprites
  843.       endif
  844.        LD (scaneof),HL
  845.         LD HL,MONSTRS+1 ;1+начало табл.монстров/предметов
  846.         ld hx,-1 ;monster index
  847.        jp SCMONS0 ;цикл скан-я видимых монстров/предметов
  848. SCMONNx
  849.         LD A,L
  850.         ADD A,8
  851.         LD L,A
  852.         JR C,SCMxIH
  853. SCMONS0
  854.        inc hx ;monster index
  855.         LD A,(HL) ;X
  856.         INC A
  857.        RET Z
  858. scmonX=$+1
  859.         SUB 0
  860.         CP viewrange*2+1
  861.         JP NC,SCMONNx
  862.         INC L
  863.         inc L
  864.         LD A,(HL)
  865. scmonY=$+1
  866.         SUB 0
  867.         CP viewrange*2+1
  868.         JR C,SCMONY
  869.         LD A,L
  870.         ADD A,6
  871.         LD L,A
  872.         JP NC,SCMONS0
  873. SCMxIH  INC H
  874.         JP SCMONS0
  875. SCMONY  DEC L
  876.         dec L
  877.         dec L
  878.         LD C,(HL)
  879.         INC L
  880.         LD B,(HL) ;Xx
  881.         INC L
  882.         LD E,(HL)
  883.         INC L
  884.         LD D,(HL) ;Yy
  885.         INC L
  886.    PUSH HL
  887.         PUSH BC
  888.        LD L,(HL) ;TYPE = 1..63
  889.        LD B,0
  890.        ld H,B
  891.         ADD HL,HL
  892.         ADD HL,HL
  893.         ADD HL,HL
  894.         LD BC,MONSTAB-8
  895.         ADD HL,BC
  896.        LD A,(HL) ;ID текстуры
  897.       if !atm
  898.       ;jr $
  899.       add a,a;ld a,r
  900.       and 6;2
  901.       add a,0xc0+(12*2);0xea
  902.       endif
  903.        ld lx,a
  904.         POP BC
  905. ;calculate sprite position
  906.         LD HL,(curYy)
  907.         SBC HL,DE ;Yy
  908.         EXD
  909.         LD HL,(curXx)
  910.         SBC HL,BC ;Xx
  911.         CALL OBJMUL
  912.        ;BC=dist
  913.        ;DE=xscr
  914.        IF lores
  915.         SRA D
  916.         RR E
  917.        ENDIF
  918.         LD HL,pixperchr*scrwid/2-256
  919.         SBC HL,DE
  920.         INC H
  921.        jr NZ,SCANnSPR ;X out of screen
  922.        IF lores
  923.         BIT 7,L
  924.        jr NZ,SCANnSPR ;X out of screen
  925.        ENDIF
  926. ;write data to cursprites
  927. ;ID 8 (0=end)
  928. ;dist 16
  929. ;xscr 8
  930. ;monster index
  931.        if DOSORTSPRITES == 0
  932.         LD A,L ;xscr
  933. scaneof=$+1
  934.         ld hl,0
  935.         ld e,lx
  936.         ld (hl),e ;id
  937.         inc l
  938.         ld (hl),c
  939.         inc l
  940.         ld (hl),b ;bc=dist
  941.         inc l
  942.         ld (hl),a ;xscr
  943.         inc l
  944.        if CURSPRITES_RECSZ == 5
  945.        ld a,hx
  946.        ld (hl),a ;monster index
  947.        inc l
  948.        endif
  949.         ld (hl),0
  950.         ld (scaneof),hl
  951.        else
  952.  
  953.        PUSH BC
  954.         EXX
  955.        POP BC
  956.         LD HL,cursprites+((-(CURSPRITES_RECSZ-2))&0xff)
  957. SCANsort0
  958.        if CURSPRITES_RECSZ == 5
  959.         INC L
  960.        endif
  961.         INC L
  962.         inc L
  963.         LD A,(HL)
  964.         OR A
  965.         jr Z,SCANins
  966.         INC L
  967.         LD E,(HL)
  968.         INC L
  969.         LD D,(HL) ;de=dist
  970.         EXD
  971.         SBC HL,BC
  972.         EXD
  973.         jr NC,SCANsort0
  974.         DEC L
  975.         dec L
  976. SCANins
  977.        PUSH BC
  978. scaneof=$+1
  979.         LD DE,0
  980.         LD A,E
  981.         SUB L
  982.         INC A ;bytes to move
  983.         LD C,A
  984.         LD B,0
  985.         LD H,D
  986.         ld L,E
  987.         LD A,E
  988.         ADD A,CURSPRITES_RECSZ;4
  989.         LD E,A
  990.         LD (scaneof),A
  991.         LDDR
  992.         INC HL
  993.        POP BC
  994.        LD A,lx;1
  995. ;A=ID текстуры
  996. ;BC'=dist
  997. ;L'=xscr
  998.         LD (HL),A
  999.         INC L
  1000.         LD (HL),C
  1001.         INC L
  1002.         LD (HL),B
  1003.         INC L
  1004.         EXX
  1005.         LD A,L
  1006.         EXX
  1007.         LD (HL),A ;xscr
  1008.         INC L
  1009.        if CURSPRITES_RECSZ == 5
  1010.        ld a,hx
  1011.        ld (hl),a ;monster index
  1012.        inc l
  1013.        endif
  1014.         EXX
  1015.        endif
  1016. SCANnSPR ;
  1017.  
  1018.    POP HL
  1019.         INC L
  1020.         inc L
  1021.         inc L
  1022.         inc HL
  1023.        INC L
  1024.         JP SCMONS0
  1025.  
  1026. DRAWSPRITES
  1027. ;ID 8 (0=end)
  1028. ;dist 16
  1029. ;xscr 8
  1030. ;monster index
  1031.         LD IY,cursprites
  1032. DRAWSPRITES0 ;
  1033.         LD A,(IY) ;id
  1034.         OR A
  1035.         RET Z
  1036.         INC IY
  1037.         LD C,(IY)
  1038.         INC IY
  1039.         LD B,(IY) ;bc=dist
  1040.         INC IY
  1041. ;A=ID
  1042.         if atm==0
  1043.         EXX
  1044.          LD D,a;#EA ;ID
  1045.          ;ld d,0xea ;ID ;TODO
  1046.         EXX
  1047.         endif
  1048.         add a,a
  1049.         add a,a
  1050.         ld hl,tsprites-4
  1051.         add a,l
  1052.         ld l,a
  1053.         jr nc,$+3
  1054.          inc h
  1055.         ld a,(hl)
  1056.         if atm
  1057.         ld (drawspritepg),a
  1058.         endif
  1059.         inc hl
  1060.         ld a,(hl)
  1061.        LD HX,a;#80+22;#C0 ;texx_center ;TODO на 48К что-то не то
  1062.        ;ld hx,22/2
  1063.         inc hl
  1064.         ld a,(hl)
  1065.         if atm
  1066.         ld (drawspritetexxleft),a
  1067.         endif ;TODO
  1068.         inc hl
  1069.         ld a,(hl)
  1070.         if atm
  1071.         ld (drawspritetexxright),a
  1072.         endif ;TODO
  1073.         LD L,(IY) ;xscr
  1074.         INC IY
  1075.        if CURSPRITES_RECSZ == 5
  1076.         INC IY
  1077.        endif
  1078. ;L=xscr
  1079. ;BC=dist
  1080.         INC B
  1081.         DJNZ gFILLNCLOSE
  1082.         LD A,108;64 ;от этого числа зависит только ширина спрайта при максимальном приближении, но не максимальная высота (она ограничена этим числом и сравнением дальше, закомментированным) ;108 чуть ниже ATM экрана, 128 запас около 8 пикс снизу
  1083.         CP C
  1084.          jr nc,DRAWSPRITES0 ;лампы не уменьшаем ;TODO уметь отличать врагов от ламп
  1085.         jr C,$+3
  1086.         LD C,A ;спрайт слишком близко!!! уменьшим
  1087. gFILLNCLOSE
  1088.        PUSH BC ;dist
  1089. ;приводим к 128..255
  1090.         LD DE,#000
  1091.         INC B
  1092.         DEC B
  1093.         LD A,C
  1094.         jr Z,MOTOLOGRLQ
  1095.        DUP 5;6
  1096.         INC D
  1097.         SRL B
  1098.         RRA
  1099.         jr Z,MOTOLOGRLE
  1100.        EDUP
  1101. MOTOLOGRLQ ;
  1102.         ;OR A
  1103.         ;JP M,$+5 ;>=128
  1104.         ;LD A,128 ;<128
  1105.         ;;cp 96
  1106.         ;;jr nc,$+4
  1107.         ;;ld a,96 ;спрайт слишком близко!!! увеличим dist для уменьшения высоты
  1108. MOTOLOGRLE ;
  1109.         LD C,A ;128..255 ;D=0..5
  1110.         LD B,tlogd/256
  1111.         LD A,(BC) ;log(dist) = 128..255 for arg>=128
  1112.        if atm==0
  1113.        SUB 16;64                 ;0..127 for arg=64..127 ;???
  1114.        endif
  1115.         LD C,A                ;0 for arg<64
  1116.         LD B,tlogd2sca/256
  1117.          SRA D
  1118.          RR E ;DE=+0,+#80,..+#300
  1119.         EXD
  1120.         ADD HL,BC
  1121.         LD C,(HL) ;scale#
  1122.         EXD
  1123.       ;
  1124.        POP DE ;dist
  1125.        if atm
  1126.         ld a,l
  1127.         ld h,d
  1128.         ld l,e
  1129.         srl h
  1130.         rr l
  1131.         add hl,de
  1132.         ex de,hl ;de = de * 1.5
  1133.         ld l,a
  1134.        else
  1135.        IF loresspr
  1136.         SLA E
  1137.         RL D
  1138.        ENDIF
  1139.         SLA E
  1140.         RL D ;DE=texx step = de * 4
  1141.        endif
  1142.  
  1143.        IF loresspr_hires|optresspr
  1144.        RES 0,L
  1145.        ENDIF
  1146.         LD H,distbuf/256+2 ;ID,texx,dist
  1147.         LD A,C ;scale#
  1148.         CP (HL)
  1149.          if !atm
  1150.          ld hx,0xc0 ;TODO
  1151.          endif
  1152.         CALL NC,DRAWSPRITE ;object center is visible ;TODO независимо от видимости центра
  1153.         JP DRAWSPRITES0
  1154.  
  1155. ;умножение
  1156. ;A=+-0.7
  1157. ;HL=A*DE
  1158.     ;A сохраняется!!!
  1159. MULT
  1160.         LD HL,0
  1161. MULTADD
  1162.         RLCA
  1163.         JR NC,MULTPLU
  1164.         DUP 6
  1165.         SRA D
  1166.         RR E
  1167.         RLCA
  1168.         JR C,$+4
  1169.         SBC HL,DE
  1170.         EDUP
  1171.         RLCA
  1172.         RET C
  1173.         SRA D
  1174.         RR E
  1175.          OR A
  1176.         SBC HL,DE
  1177.         RET
  1178. MULTPLU DUP 6
  1179.         SRA D
  1180.         RR E
  1181.         RLCA
  1182.         JR NC,$+3
  1183.         ADD HL,DE
  1184.         EDUP
  1185.         RLCA
  1186.         RET NC
  1187.         SRA D
  1188.         RR E
  1189.         ADD HL,DE
  1190.         RET
  1191.  
  1192. OBJMULQ
  1193.         POP AF ;X
  1194.        LD D,#40 ;X out of screen
  1195.         RET
  1196. ;пересчет координат объекта (Xx=HL, Yy=DE)
  1197. ;в координаты на экране (DE=xscr, BC=расстояние)
  1198. OBJMUL
  1199.         PUSH HL ;X
  1200.        PUSH DE ;Y
  1201.        PUSH HL ;X
  1202.         LD HL,(curangle) ;L=центр взгляда
  1203.         LD C,(HL) ;sin=шаг по Y
  1204.         LD A,-64
  1205.         SUB L
  1206.         LD L,A
  1207.         LD B,(HL) ;-COS=шаг по X
  1208.    ;Bc=DXdy=COSsin
  1209.         LD A,C
  1210.         CPL
  1211.         CALL MULT ;HL=A*DE=-sin*Y
  1212.        POP DE ;X
  1213.         LD A,B
  1214.         CALL MULTADD ;HL=-COS*X-sin*Y=d(расстояние по объекта)
  1215.        POP DE ;Y
  1216.         BIT 7,H
  1217.         jr NZ,OBJMULQ ;если расстояние<0,то объект за спиной=>exit
  1218.         LD (_OBJd1),HL
  1219.         CALL MULT;A=B=-COS, HL=-COS*Y
  1220.        POP DE ;X
  1221.         LD A,C
  1222.         CALL MULTADD ;HL=-COS*Y+sin*X=xscr*d
  1223.         EXD
  1224. _OBJd1=$+1
  1225.         LD BC,0 ;BC=d ;после MONDIV получим DE=xscr
  1226.         ;jp MONDIV
  1227.        ENDIF ;sprites
  1228. ;деление
  1229. ;DE=+-7.8;BC=+7.8
  1230. ;DE=DE/BC=+-8.7/2
  1231.     ;BC сохраняется!!!
  1232. MONDIV
  1233.         LD H,0
  1234.         LD A,D
  1235.         SLA E
  1236.         RLA
  1237.         JP C,MONDIVNEG ;если делимое<0
  1238.         LD L,A
  1239.         INC E
  1240.         LD A,E
  1241.        DUP 7
  1242.         SBC HL,BC
  1243.         JR NC,$+3
  1244.         ADD HL,BC
  1245.         RLA
  1246.         ADC HL,HL
  1247.        EDUP
  1248.         CPL
  1249.         LD D,A
  1250.        DUP 7
  1251.         SBC HL,BC
  1252.         JR NC,$+3
  1253.         ADD HL,BC
  1254.         RLA
  1255.         ADD HL,HL
  1256.        EDUP
  1257.         SBC HL,BC
  1258.         JR NC,$+3
  1259.         ADD HL,BC
  1260.         RLA
  1261.         CPL
  1262.         LD E,A
  1263.         RET
  1264. ;если делимое<0
  1265. MONDIVNEG
  1266.         CPL
  1267.         LD L,A
  1268.         SBC A,A
  1269.         XOR E
  1270.        DUP 7
  1271.         SBC HL,BC
  1272.         JR NC,$+3
  1273.         ADD HL,BC
  1274.         RLA
  1275.         ADC HL,HL
  1276.        EDUP
  1277.         LD D,A
  1278.        DUP 7
  1279.         SBC HL,BC
  1280.         JR NC,$+3
  1281.         ADD HL,BC
  1282.         RLA
  1283.         ADD HL,HL
  1284.        EDUP
  1285.         SBC HL,BC
  1286.         JR NC,$+3
  1287.         ADD HL,BC
  1288.         RLA
  1289.         LD E,A
  1290.         RET
  1291.