Subversion Repositories NedoOS

Rev

Rev 82 | Rev 344 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download

  1. FRIY2  ;DS #404;from ldlens
  2. ldlens  DS 298
  3. ddlens  DS 48
  4. rdlens  DS 28 ;#2AA+256
  5. FRIY2ln=$-FRIY2
  6.  
  7. disp    DS 3
  8.  
  9. ARCBEG  DS 7 ;FIRST 7 BYTES OF RAR
  10.  
  11.         align 256
  12. bdlens=$-19
  13. HEXBUF=$-19;24;TOO MUCH
  14. DECBUF ;DB 0
  15. ;begin
  16. midBT ;ъЁєуы√щ рфЁхё!
  17. ;tree added 3,bits sub L(bits=0 юёЄртыхэю)
  18.       ;L=00   2   4   6   8   A   C   E
  19.      db #00,#03,#00,#04,#00,#05,#00,#06,#00,#07,#00,#08,#00,#09,#00,#0A
  20.         ;10  12  14  16  18  1A  1C  1E
  21.      db #F1,#0B,#EF,#0D,#ED,#0F,#EB,#11,#EA,#13,#E8,#17,#E6,#1B,#E4,#1F
  22.         ;20  22  24  26  28  2A  2C  2E
  23.      db #E3,#23,#E1,#2B,#DF,#33,#DD,#3B,#DC,#43,#DA,#53,#D8,#63,#D6,#73
  24.         ;30  32  34  36
  25.      db #D5,#83,#D3,#A3,#D1,#C3,#CF,#E3
  26.  
  27. ;tree added 1
  28. litBT  db #02,#01,#02,#05,#03,#09,#04,#11,#05,#21,#06,#41,#06,#81,#06,#C1
  29.        DISPLAY litBT,"(don't cross 256)",$
  30. ;added 1
  31. bigBT   db #00,#00,#01,#00
  32.         db #00,#00,#02,#00
  33.         db #00,#00,#03,#00
  34.         db #00,#00,#04,#00
  35.         db #00,#01,#05,#00
  36.         db #00,#01,#07,#00
  37.         db #00,#02,#09,#00
  38.         db #00,#02,#0D,#00
  39.         db #00,#03,#11,#00
  40.         db #00,#03,#19,#00
  41.         db #00,#04,#21,#00
  42.         db #00,#04,#31,#00
  43.         db #00,#05,#41,#00
  44.         db #00,#05,#61,#00
  45.         db #00,#06,#81,#00
  46.         db #00,#06,#C1,#00
  47.         db #00,#07,#01,#01
  48.         db #00,#07,#81,#01
  49.         db #00,#08,#01,#02
  50.         db #00,#08,#01,#03
  51.         db #00,#09,#01,#04
  52.         db #00,#09,#01,#06
  53.         db #00,#0A,#01,#08
  54.         db #00,#0A,#01,#0C
  55.         db #00,#0B,#01,#10
  56.         db #00,#0B,#01,#18
  57.         db #00,#0C,#01,#20
  58.         db #00,#0C,#01,#30
  59.         db #00,#0D,#01,#40
  60.         db #00,#0D,#01,#60
  61.         db #00,#0E,#01,#80
  62.         db #00,#0E,#01,#C0
  63.         db #01,#0F,#01,#00
  64.         db #01,#0F,#01,#80
  65.         db #02,#10,#01,#00
  66.         db #03,#10,#01,#00
  67.         db #04,#10,#01,#00
  68.         db #05,#10,#01,#00
  69.         db #06,#10,#01,#00
  70.         db #07,#10,#01,#00
  71.         db #08,#10,#01,#00
  72.         db #09,#10,#01,#00
  73.         db #0A,#10,#01,#00
  74.         db #0B,#10,#01,#00
  75.         db #0C,#10,#01,#00
  76.         db #0D,#10,#01,#00
  77.         db #0E,#10,#01,#00
  78.         db #0F,#10,#01,#00
  79.                      
  80. DEPK
  81.         if 1==0
  82.         LD HL,s8
  83.         LD DE,8
  84.         LD BC,#105
  85.        ;LD HY,B ;¤Єю с√ыр чр∙шЄр юЄ im 1, ўЄюс√ ьюцэю с√ыю шёяюы№чютрЄ№ ly (яюф ьы. срщЄ юёЄрЄър фышэ√ Їрщыр) TODO
  86.         CALL DOD
  87.         LD HL,(s8+#E1)
  88.        ;LD A,(doSAVEk)
  89.        ;SUB "y"
  90.        ;JR NZ,$+4
  91.        ;LD H,A,L,A ;depack as trd
  92.         LD (stsec),HL ;эрўшэр  ё ъръюую ёхъЄюЁр яш°хь
  93.         endif
  94.        
  95.         LD A,128
  96.         EXA
  97.        LD A,(FLAGF)
  98.        AND 16
  99.        JR NZ,DPsol
  100. ;;;nosolid
  101.       CALL PRTHEE
  102.         CALL RdTabs
  103.       LD A,-1
  104.       LD (restoreLAST),A
  105. ;;;~nosolid
  106. DPsol
  107.         if 1==0
  108.         LD HL,(DEPADR)
  109.          LD (gegAD),HL ;for hobeta
  110.        LD A,(doSAVEk)
  111.        CP "$"
  112.         LD A,(curPG)
  113.          LD (gegPG),A
  114.        JR NZ,nohobski
  115.         LD B,17
  116.         INC L
  117.         CALL Z,Lil
  118.         DJNZ $-4
  119.         LD (stAD),HL
  120.         LD (stPG),A
  121. nohobski
  122.         endif
  123.  
  124.         LD HL,uNPremn
  125.         LD A,(HL)
  126.        ;LD (SAVElenLS1),A
  127.         XOR A
  128.         SUB (HL)
  129.         LD lx,a;LY,A ;TODO fix, ўЄю-Єю эх Єръ ё фышэющ Ёрёяръютрээюую Їрщыр
  130.         INC HL
  131.         LD A,0
  132.         SBC A,(HL)
  133.         LD (HL),A
  134.         LD C,A
  135.         INC HL
  136.         SBC A,A
  137.         SUB (HL)
  138.         LD (HL),A
  139.         LD B,A
  140.        RET Z
  141.       if frmcnt
  142.         ex af,af'
  143.        push af
  144.          push bc
  145.        push ix
  146.        push iy
  147.        OS_GETTIMER ;hlde=timer
  148.        pop iy
  149.        pop ix
  150.          pop bc
  151.        pop af
  152.        ex af,af'
  153.         LD (wastimer),de
  154.       ENDIF
  155.         XOR A
  156.         LD L,A
  157.         ld H,L
  158.       if frmcnt
  159.       LD (swaps),HL
  160.       ENDIF
  161.         SBC HL,BC
  162.         ;LD (SAVEsz),HL ;??? TODO
  163.         LD (SAVErmn),HL
  164.         CALL OUTcur
  165. DEPADR=$+1
  166.         LD DE,0;THEEND
  167.          CALL DEPK0
  168.         LD (DEPADR),DE
  169.        ;LD IY,23610
  170. ;;;
  171.       if frmcnt
  172.        call RST16
  173.        DB #D,#a,"frames=",0
  174.         OS_GETTIMER ;hlde=timer
  175.         ex de,hl
  176. wastimer=$+1
  177.         ld de,0
  178.         or a
  179.         sbc hl,de
  180.        LD A,5
  181.        CALL PRDEC
  182.        call RST16
  183.        DB "+swaps=",0
  184. swaps=$+1
  185.        LD HL,0
  186.        LD A,5
  187.        CALL PRDEC
  188.       ENDIF
  189.         jp SAVE
  190.  
  191. DEPK0i
  192.         LD HL,uNPremn+1
  193.         INC (HL)
  194.        ;jr $
  195.        JR NZ,DEPK0
  196.        JP GPqI
  197.  
  198. NEWDEMN
  199. ;?/frame
  200.         ;LD A,(IX)
  201.         ;INC LX
  202.         ;CALL Z,LDAsec
  203.         rarrdbyte
  204.         SCF
  205.         RLA
  206.         JR C,DEMNC
  207.         JP DEMNNC
  208. yBs
  209.         CALL store
  210.         JP yBse
  211. yBYTE
  212.      EXX
  213.      LD (DE),A ;page=curPG
  214.      INC E
  215.      JR Z,yBs
  216. yBse   INC lx;LY
  217.        JR Z,DEPK0i
  218. DEPK0
  219.         EXX
  220. DEPK0X
  221.         LD HL,ld
  222.         EXA
  223. DEMN0   ADD A,A
  224.         JR Z,NEWDEMN
  225.         JR NC,$+4 ;эюы№
  226. DEMNC   INC L  ;хфшэшЎр
  227.         INC L;HL
  228. DEMNNC  LD C,(HL)
  229.         INC L
  230.         LD H,(HL)
  231.         LD L,C
  232.        IF (ld/256)&#40
  233.         BIT 6,H
  234.        ELSE
  235.        if (ld/256)&#80
  236.         BIT 7,H
  237.        else
  238.        IF (ld/256)&#20
  239.         BIT 5,h
  240.        ENDIF
  241.        endif
  242.        ENDIF
  243.         JP NZ,DEMN0
  244.         EXA
  245.         LD A,C
  246. ;1.5t/frame
  247.        DEC H
  248.        JR NZ,yBYTE
  249. nBYTE
  250.         SUB 270&0xff
  251.        JP C,m270 ;<270
  252. ;270..297
  253.        ADD A,A
  254.       LD H,midBT/256
  255.        LD L,A
  256.     ;LD BC,midBT
  257.     ;ADD HL,BC
  258.        ADD A,(HL)
  259.       INC L
  260.        LD L,(HL)
  261.       LD H,0
  262.        JP NC,na270
  263.         CALL LDA18
  264.         ADD HL,BC
  265. na270
  266.       PUSH HL;!!!!!!!
  267.       ;jr $
  268.         LD HL,dd
  269.         CALL DEHUFF
  270.        SLA L
  271.        sla L
  272.       LD BC,bigBT
  273.       ADD HL,BC
  274.        ;LD H,'bigBT
  275.         XOR A
  276.         OR (HL)
  277.         LD (disp+2),A
  278.        JR NZ,diN0
  279.         INC L
  280.         ADD A,(HL)
  281.        JR Z,diNADD
  282.         INC L
  283.         CALL LDA
  284.         LD A,(HL)
  285.         INC L
  286.         LD H,(HL)
  287.         LD L,A
  288.         ADD HL,BC
  289.         LD (disp),HL
  290.         JR C,dIIputs
  291. ;3t/frame
  292.         LD A,H
  293.       POP HL ;!!!!!!!
  294.         CP #20
  295.        JP C,putsPUT
  296.         INC HL
  297.        JP putsPUT
  298. dIIputs LD A,1
  299.         JP eIIputs
  300. diNADD
  301.         INC L
  302.         LD A,(HL)
  303.         LD (disp),A
  304.         LD HL,0
  305.         LD (disp+1),HL
  306.       POP HL ;!!!!!!!
  307.        JP putsPUT
  308. diN0
  309. ;10t/frame
  310.         INC L
  311.        LD A,(HL) ;#F/#10
  312.         INC L
  313.         CALL LDA
  314.         LD A,(HL)
  315.         INC L
  316.         LD H,(HL)
  317.         LD L,A
  318.         ADD HL,BC
  319.         LD (disp),HL
  320.         LD A,(disp+2)
  321.         ADC A,0
  322. eIIputs
  323.         LD (disp+2),A
  324.       POP HL ;!!!!!!!
  325.         INC HL
  326.         CP 4
  327.        JP C,putsPUT
  328.         INC HL
  329.        JP putsPUT
  330. y269
  331.        EXX
  332.        PUSH DE
  333.         CALL RdTabs
  334.        POP DE
  335.        JP DEPK0
  336.  
  337. m270    INC A
  338.        JR Z,y269 ;269
  339. n256    ADD A,8
  340.        JP C,br261 ;261..268
  341.         ADD A,4
  342.        JP NC,GETPUT;256
  343. ;257..260->0..3
  344.        RRCA
  345.        RRCA
  346.       LD HL,(ind03)
  347.       ADD A,L
  348.       LD L,A
  349.       ;only +5 frames:
  350.       ;LD B,0
  351.       ;DJNZ $
  352.        LD DE,disp
  353.        LDI
  354.        LDI
  355.        LDI
  356.        ;jr $
  357.         LD HL,rd
  358.         CALL DEHUFF
  359.        SLA L
  360.     ;LD BC,midBT
  361.     ;ADD HL,BC
  362.        LD H,midBT/256
  363.        LD A,L
  364.         ADD A,(HL)
  365.         INC L
  366.         LD L,(HL)
  367.        LD BC,0
  368.        LD H,B
  369.         CALL C,LDA18
  370.         ADD HL,BC
  371.         LD A,(disp+2)
  372.         CP 4
  373.         JR C,$+3
  374.         INC HL
  375.       ;INC HL
  376.         OR A
  377.         JR NZ,I1puts
  378.         LD BC,(disp)
  379.         LD A,B
  380.         CP #20
  381.         JR NC,I1puts
  382.        DEC HL
  383.         DEC BC
  384.         DEC B
  385.        JP M,putsPUT
  386. I1puts  INC HL
  387.        JP putsPUT
  388. ;261..268
  389. br261  ADD A,A
  390.        LD HL,litBT
  391.       ADD A,L
  392.        LD L,A
  393.        LD A,(HL)
  394.        INC L
  395.         LD L,(HL)
  396.         CALL LDA18
  397.         LD H,B
  398.         ADD HL,BC
  399.         LD (disp),HL
  400.       XOR A
  401.       LD (disp+2),A
  402.         LD HL,2
  403. putsPUT
  404.        LD (puts),HL
  405. GETPUT
  406. ;2t/frame in haets20.rar
  407. ind03=$+1
  408.        LD HL,TAB44
  409.        LD A,L
  410.        SUB 64
  411.        LD L,A
  412.        LD (ind03),A
  413.         LD A,(disp)
  414.         LD (HL),A
  415.         INC L
  416.         LD BC,(disp+1)
  417.         LD (HL),C
  418.         INC L
  419.         LD (HL),B
  420. _2      LD HL,+(1-INITIALMEMPAGES)*64+(THEEND/256)-256 ;INITIALMEMPAGES;6 = ўшёыю ёЄЁрэшЎ ярь Єш?
  421.         ADD HL,BC
  422. GPaddrpatch=$+1
  423.         JP NC,GPmem ;яюфьхэ хЄё  эр ъюяш■ p48 (юЁшушэры p48 ъюяшЁєхЄё  яютхЁї юъюэўрэш  GPmem, Є.ъ. шчэрўры№эю шэшЎшрышчрЄюЁ чрЄшЁрыё , ш p48 Єюцх, ш Єръ с√ёЄЁхх т√їюф шч p48)
  424.         ;jr $ ;ё■фр эх яюярфрхь
  425.        
  426. ;TODO
  427.         if 1==0
  428. GPdisk
  429. ;уы■ўшЄ :(
  430. ;FROM=disk
  431. ;solid shift
  432.         EXX
  433.         PUSH DE
  434.         EXX
  435.         POP HL
  436.        LD BC,(stAD)
  437.        LD B,0
  438.        OR A
  439.        SBC HL,BC
  440. ;
  441.        LD B,A
  442.        LD A,L
  443.        SUB B
  444.        PUSH AF
  445. ;beg.buf on disk=stsecnw
  446. ;sub secs back
  447.        PUSH AF
  448.         LD A,(curPG)
  449.         SLA H
  450.         sla H
  451.       ADC A,0 ;V0.42
  452.         RRA
  453.         RR H
  454.         RRA
  455.         RR H
  456.         LD L,H
  457.         ld H,A
  458.        POP AF
  459.         LD BC,(disp+1)
  460.         SBC HL,BC
  461.      ;LD BC,0   ;#80-'THEEND
  462.      ;ADD HL,BC ;???
  463. ;HL=secs add
  464.         dup 4
  465.         add hl,hl
  466.         edup
  467. stsecnw=$+1 ;C<<4
  468.        LD BC,0
  469.         ADD HL,BC
  470. ;       JR C,notr0
  471. ;       LD A,H
  472. ;       ADD A,160
  473. ;       LD H,A
  474. ;notr0
  475.         LD A,L
  476.         RRCA
  477.         RRCA
  478.         RRCA
  479.         RRCA
  480.         LD L,A
  481.        LD (resec),HL
  482.        EXX
  483.        CALL restore
  484.         POP AF
  485.         LD L,A
  486.        LD BC,(puts)
  487.         ADD A,C
  488.         LD A,(curPG)
  489.         DEC B
  490.        JR Z,GPftor
  491.        JR C,GPftor
  492.         LD B,D
  493.         INC B
  494.        JP NZ,GPmfst
  495.         DEC B ;B=-1
  496. GPftor  INC B
  497.         CALL OUTME
  498. GPf1    LD A,(HL)
  499.         LD (DE),A
  500.         INC L
  501.         CALL Z,restore ;read known sector from destination file
  502.         INC E
  503.         CALL Z,store
  504.         DEC BC
  505.         LD A,B
  506.         OR C
  507.         JR NZ,GPf1
  508.         endif
  509. GPqSLOW
  510.         LD HL,(puts)
  511.         LD C,lx;LY
  512.         LD A,(uNPremn+1)
  513.         LD B,A
  514.         ADD HL,BC
  515.         LD A,L
  516.         LD lx,a;LY,A
  517.         LD A,H
  518.         LD HL,uNPremn+1
  519.         LD (HL),A
  520.        JP NC,DEPK0
  521.        JP GPqI
  522.        
  523. GPmem
  524.         EXX
  525.        LD H,D
  526.        ld L,E
  527.        LD BC,(disp)
  528.         LD A,(curPG)
  529.         SLA H
  530.         sla H ;CY=1
  531.       ADC A,-1;V0.42
  532.         RRA
  533.         RR H ;CY=0
  534.         RRA
  535.         RR H ;CY=0
  536. ;AHL=adrinbuf-hwost
  537.         SBC HL,BC
  538.        EXX
  539.        SBC A,B
  540.        EXX
  541.        ;RL H
  542.        ;RLA
  543.        ;RL H
  544.        ;ADC A,A ;CY=1 or M
  545.        ;JP P,$+5
  546.      ;V0.42
  547.         RL H
  548.         RLA
  549.         RL H
  550.         RLA
  551.         SCF
  552.         RR H
  553.         SCF
  554.         RR H
  555.        CP 128 ;ўЄю ¤Єю? TODO
  556.        JR C,GPendif
  557.         LD C,A ;ўЄю ¤Єю? TODO
  558.         LD A,H
  559.         ADD A,#C0-(THEEND/256)
  560.         JR NC,GPelse
  561.         INC C
  562.         JR Z,GPthen
  563. GPelse  OR 192
  564.         LD H,A
  565. _p1      LD A,INITIALMEMPAGES;6 ;ўшёыю ёЄЁрэшЎ ярь Єш?
  566.         ADD A,C
  567.         JR C,GPendif
  568. GPthen  RES 6,H
  569.         XOR A
  570. GPendif
  571. GPmemsz=$-GPmem
  572.         LD (frPG),A
  573. puts=$+1
  574.         LD BC,0 ;2..261
  575.         DEC B
  576.        JR Z,GPmtor
  577.         LD B,D
  578.         INC B
  579.        JR Z,GPmt2
  580.         LD B,H
  581.         INC B
  582.        JR Z,GPmt2
  583. curPG=$+1
  584.         CP 0
  585.        JR NZ,GPmt3
  586. GPmfst
  587.         LD B,0
  588.        LD A,C
  589.         LDIR
  590. GPq
  591.        ADD A,lx;LY
  592.        LD lx,a;LY,A
  593.        JP NC,DEPK0
  594.         LD HL,uNPremn+1
  595.         INC (HL)
  596.        JP NZ,DEPK0
  597. GPqI    INC HL
  598.         INC (HL)
  599.        JP NZ,DEPK0
  600.         RET
  601.  
  602. GPm2    LD A,(frPG)
  603. GPmt2   CALL OUTME
  604.         LD B,(HL)
  605.         INC L
  606.         CALL Z,corFROM
  607.         CALL OUTcur
  608.         LD A,B
  609.         LD (DE),A
  610.         INC E
  611.         CALL Z,store
  612.         DEC C
  613.         JP NZ,GPm2
  614.         JR GPe
  615.  
  616. ;t=2f
  617. GPm3    LD A,(frPG)
  618. GPmt3   CALL OUTME
  619.         LD A,(HL)
  620.         PUSH AF
  621.         INC L
  622.         CALL Z,corFROM
  623.         LD B,(HL)
  624.         INC L
  625.         CALL Z,corFROM
  626. curPG2=$+1
  627.         LD A,0
  628.         CALL OUTME
  629.         POP AF
  630.         LD (DE),A
  631.         INC E
  632.         CALL Z,store
  633.         DEC C
  634.         JR Z,GPe
  635.         LD A,B
  636.         LD (DE),A
  637.         INC E
  638.         CALL Z,store
  639.         DEC C
  640.         JP NZ,GPm3
  641. GPe     LD A,(puts)
  642.         JP GPq
  643.  
  644. GPmtor  INC B
  645. GPm0tor LD A,(frPG)
  646.         CALL OUTME
  647.         LD A,(HL)
  648.        PUSH AF
  649.         INC L          ;
  650.         CALL Z,corFROM ;v0.60!
  651.         CALL OUTcur
  652.        POP AF
  653.         LD (DE),A
  654.         INC E
  655.         CALL Z,store
  656.         DEC BC
  657.         LD A,B
  658.         OR C
  659.         JR NZ,GPm0tor
  660.        JP GPqSLOW
  661. store
  662.         INC D
  663.         RET NZ
  664.         LD A,(curPG)
  665.         INC A
  666.         LD D,#C0
  667. _4      CP INITIALMEMPAGES;6 ;ўшёыю ёЄЁрэшЎ ярь Єш?
  668.         JR Z,storer
  669.         jp OUTMEcu
  670.  
  671. storer
  672. ;first store - ADDR to ENDMEM,
  673. ; ADDR=bufstor+hwostik
  674. ;posledujushie - ADDR to ENDMEM
  675. ;hwostik ENDMEM -> bufstor, save next time
  676. ; iz SAVErmn ne wychitaetsa
  677.  
  678. ;SAVE saves ADDR, (SAVErmn) SECTORS.
  679.        IF border
  680.         LD A,4
  681.         OUT (-2),A
  682.        ENDIF
  683.         PUSH BC,HL
  684.         push iy;IX
  685.         CALL SAVbeg
  686. ;HL=addr,A=page
  687.       PUSH AF
  688. storePG0
  689.         LD A,H
  690.         INC A
  691.         JR NZ,nRAZLOM
  692.         LD DE,bufstor
  693.         PUSH DE
  694.         LD B,A
  695.         SUB L
  696.         LD C,A
  697.        DEC C
  698.        INC BC
  699.         EXA
  700.         INC A
  701. _5      CP INITIALMEMPAGES;6 ;ўшёыю ёЄЁрэшЎ ярь Єш?
  702.        JR Z,storQQQ
  703.         LDIR
  704.         LD H,#C0 ;V0.42
  705.        PUSH AF
  706.         CALL OUTME
  707.        POP AF
  708.         EXA
  709.         XOR A
  710.         SUB E
  711.         JR Z,$+5
  712.         LD C,A
  713.         LDIR
  714.        DEC H
  715.         LD A,1
  716.         JR yRAZLOM
  717. nRAZLOM
  718.         PUSH HL
  719.         NEG
  720. yRAZLOM LD E,A
  721.         ADD A,H
  722.         LD H,A
  723.         EX (SP),HL
  724.        PUSH DE
  725. ;e=number of sectors to save
  726. ;hl=addr
  727.         if 1==1
  728.         ld d,e
  729.         ld e,0
  730.         call SAVEBLOCK
  731.         else
  732.        
  733.         LD C,6
  734.         LD B,E
  735. stsec=$+1
  736.         LD DE,0
  737.         CALL DOD
  738.         LD HL,(#5CF4)
  739.         LD (stsec),HL
  740.        
  741.         endif
  742.        
  743.        POP DE
  744. SAVErmn=$+1
  745.         LD HL,0
  746.         XOR A
  747.         LD D,A ;de=number of sectors to save (saved)
  748.         SBC HL,DE
  749.         LD (SAVErmn),HL
  750.         POP HL
  751.        JR storePG0
  752. storQQQ
  753.        POP AF ;de
  754.         LD E,L
  755.         PUSH DE
  756.         LDIR
  757.         POP HL
  758.  
  759.         if 1==0
  760. ;TODO ¤Єю фы  тючьюцэюёЄш ўЄхэш  єцх чряшёрээюую
  761. ;TODO фышэє ёюїЁрэ хьюую Їрщыр - SAVErmn*256, ёфхырЄ№ SEEK, яЁюўшЄрЄ№, р яюЄюь SEEK юсЁрЄэю (сєфхЄ ыш ¤Єю ЁрсюЄрЄ№ т FATFS? т TRDOSFS эх сєфхЄ)
  762.        PUSH HL
  763.        LD DE,(stsec)
  764.        LD BC,#106
  765.        CALL DOD
  766.         LD HL,(#5CF4)
  767.         LD A,L
  768.         ADD A,A
  769.         add A,A
  770.         add A,A
  771.         add A,A
  772.         LD L,A
  773.         LD (stsecnw),HL
  774.        POP HL
  775.         endif
  776.  
  777.       POP AF
  778.         EXA
  779.         XOR A ;!
  780.        IF border
  781.         OUT (-2),A
  782.        ENDIF
  783.         LD (stPG),A
  784.         LD (stAD),HL
  785.         LD DE,THEEND
  786.         POP iy;IX
  787.         pop HL,BC
  788.         JP OUTMEcu
  789. corFROM
  790.         INC H
  791.         RET NZ
  792. frPG=$+1
  793.         LD A,0
  794.         INC A
  795.         LD (frPG),A
  796.         LD H,#C0
  797. _3      CP INITIALMEMPAGES;6 ;ўшёыю ёЄЁрэшЎ ярь Єш?
  798.         JP NZ,OUTME
  799.         XOR A
  800.         LD H,THEEND/256
  801.         LD (frPG),A
  802.         JP OUTME
  803.  
  804. Lil     INC H
  805.         RET NZ
  806.         LD H,#C0
  807.         INC A
  808. L_pg    CP 0
  809.         JR NZ,$+5
  810.         XOR A
  811.         LD H,THEEND/256
  812.         LD C,A
  813.         CALL OUTME
  814.         LD A,C
  815.         RET
  816.