Subversion Repositories NedoOS

Rev

Rev 2266 | Blame | Compare with Previous | Last modification | View Log | Download

  1. ; Simple printing module.
  2. ;
  3. ; Copyright (C) 2012-2023 Patrik Rak (patrik@raxoft.cz)
  4. ;
  5. ; This source code is released under the MIT license, see included license.txt.
  6.  
  7.  
  8. printinit:  ld      a,2
  9. ;            jp      0x1601      ; CHAN-OPEN
  10.             jp      EMU_CHAN_OPEN
  11.  
  12.  
  13. print:      ex      (sp),hl
  14.             call    printhl
  15.             ex      (sp),hl
  16.             ret
  17.  
  18. printhl:
  19. .loop       ld      a,(hl)
  20.             inc     hl
  21.             or      a
  22.             ret     z
  23.             call    printchr
  24.             jr      .loop
  25.  
  26.  
  27. printdeca:  ld      h,a
  28.             ld      b,-100
  29.             call    .digit
  30.             ld      b,-10
  31.             call    .digit
  32.             ld      b,-1
  33.  
  34. .digit      ld      a,h
  35.             ld      l,'0'-1
  36. .loop       inc     l
  37.             add     a,b
  38.             jr      c,.loop
  39.             sub     b
  40.             ld      h,a
  41.             ld      a,l
  42.             jr      printchr
  43.  
  44.  
  45. printcrc:   ld      b,4
  46.  
  47. printhexs:
  48. .loop       ld      a,(hl)
  49.             inc     hl
  50.             call    printhexa
  51.             djnz    .loop
  52.             ret
  53.  
  54.  
  55. printhexa:  push    af
  56.             rrca
  57.             rrca
  58.             rrca
  59.             rrca
  60.             call    .nibble
  61.             pop     af
  62.  
  63. .nibble     or      0xf0
  64.             daa
  65.             add     a,0xa0
  66.             adc     a,0x40
  67.  
  68. printchr:   push    iy
  69.             ld      iy,0x5c3a   ; ERR-NR
  70.             push    de
  71.             push    bc
  72.             ;exx
  73.             nop
  74.  
  75. ;            ei
  76. ;            ; out     (0xff),a
  77. ;            rst     0x10
  78. ;            di
  79.             call    EMU_RST_10
  80.  
  81.             ;exx
  82.             nop
  83.  
  84.             pop     bc
  85.             pop     de
  86.             pop     iy
  87.             ret
  88.  
  89. ; EOF ;
  90.